e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
73 lines
1.8 KiB
Nix
73 lines
1.8 KiB
Nix
{
|
|
lib,
|
|
buildPythonPackage,
|
|
fetchFromGitHub,
|
|
PCSC,
|
|
pcsclite,
|
|
pkg-config,
|
|
pytestCheckHook,
|
|
setuptools,
|
|
stdenv,
|
|
swig,
|
|
}:
|
|
|
|
let
|
|
# Package does not support configuring the pcsc library.
|
|
withApplePCSC = stdenv.hostPlatform.isDarwin;
|
|
in
|
|
|
|
buildPythonPackage rec {
|
|
pname = "pyscard";
|
|
version = "2.0.9";
|
|
pyproject = true;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "LudovicRousseau";
|
|
repo = "pyscard";
|
|
rev = "refs/tags/${version}";
|
|
hash = "sha256-DO4Ea+mlrWPpOLI8Eki+03UnsOXEhN2PAl0+gdN5sTo=";
|
|
};
|
|
|
|
build-system = [ setuptools ];
|
|
|
|
nativeBuildInputs = [ swig ] ++ lib.optionals (!withApplePCSC) [ pkg-config ];
|
|
|
|
buildInputs = if withApplePCSC then [ PCSC ] else [ pcsclite ];
|
|
|
|
nativeCheckInputs = [ pytestCheckHook ];
|
|
|
|
postPatch =
|
|
if withApplePCSC then
|
|
''
|
|
substituteInPlace smartcard/scard/winscarddll.c \
|
|
--replace-fail "/System/Library/Frameworks/PCSC.framework/PCSC" \
|
|
"${PCSC}/Library/Frameworks/PCSC.framework/PCSC"
|
|
''
|
|
else
|
|
''
|
|
substituteInPlace setup.py --replace "pkg-config" "$PKG_CONFIG"
|
|
substituteInPlace smartcard/scard/winscarddll.c \
|
|
--replace-fail "libpcsclite.so.1" \
|
|
"${lib.getLib pcsclite}/lib/libpcsclite${stdenv.hostPlatform.extensions.sharedLibrary}"
|
|
'';
|
|
|
|
preCheck = ''
|
|
# remove src module, so tests use the installed module instead
|
|
rm -r smartcard
|
|
'';
|
|
|
|
disabledTests = [
|
|
# AssertionError
|
|
"test_hresult"
|
|
"test_low_level"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Smartcard library for python";
|
|
homepage = "https://pyscard.sourceforge.io/";
|
|
changelog = "https://github.com/LudovicRousseau/pyscard/releases/tag/${version}";
|
|
license = licenses.lgpl21Plus;
|
|
maintainers = with maintainers; [ layus ];
|
|
};
|
|
}
|