e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
49 lines
1.3 KiB
Nix
49 lines
1.3 KiB
Nix
{ lib, stdenv, fetchurl, cmake, pkg-config, zlib, libpng, libjpeg, giflib, libtiff
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "pslib";
|
|
version = "0.4.8";
|
|
|
|
src = fetchurl {
|
|
name = "${pname}-snixource-${version}.tar.gz";
|
|
url = "mirror://sourceforge/${pname}/${pname}-${version}.tar.gz";
|
|
sha256 = "sha256-gaWNvBLuUUy0o+HWCOyG6KmzxDrYCY6PV3WbA/jjH64=";
|
|
};
|
|
|
|
nativeBuildInputs = [ cmake pkg-config ];
|
|
buildInputs = [ zlib libpng libjpeg giflib libtiff ];
|
|
|
|
env = lib.optionalAttrs stdenv.hostPlatform.isDarwin {
|
|
NIX_CFLAGS_COMPILE = "-Wno-error=implicit-function-declaration";
|
|
};
|
|
|
|
doCheck = true;
|
|
|
|
outputs = [ "out" "dev" "doc" ];
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/lib
|
|
for path in *.dylib *.so *.so.* *.o *.o.*; do
|
|
mv $path $out/lib/
|
|
done
|
|
mkdir -p $dev/include
|
|
mv ../include/libps $dev/include
|
|
if test -d nix-support; then
|
|
mv nix-support $dev
|
|
fi
|
|
mkdir -p $doc/share/doc/${pname}
|
|
cp -r ../doc/. $doc/share/doc/${pname}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "C-library for generating multi page PostScript documents";
|
|
homepage = "https://pslib.sourceforge.net/";
|
|
changelog =
|
|
"https://sourceforge.net/p/pslib/git/ci/master/tree/pslib/ChangeLog";
|
|
license = licenses.gpl2;
|
|
maintainers = with maintainers; [ ShamrockLee ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|