e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
56 lines
1.4 KiB
Nix
56 lines
1.4 KiB
Nix
{ lib, stdenv, fetchurl, libxml2, pkg-config
|
|
, compressionSupport ? true, zlib ? null
|
|
, sslSupport ? true, openssl ? null
|
|
, static ? stdenv.hostPlatform.isStatic
|
|
, shared ? !stdenv.hostPlatform.isStatic
|
|
, bash
|
|
}:
|
|
|
|
assert compressionSupport -> zlib != null;
|
|
assert sslSupport -> openssl != null;
|
|
assert static || shared;
|
|
|
|
let
|
|
inherit (lib) optionals;
|
|
in
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "0.32.5";
|
|
pname = "neon";
|
|
|
|
src = fetchurl {
|
|
url = "https://notroj.github.io/${pname}/${pname}-${version}.tar.gz";
|
|
sha256 = "sha256-SHLhL4Alct7dSwL4cAZYFLLVFB99va9wju2rgmtRpYo=";
|
|
};
|
|
|
|
patches = optionals stdenv.hostPlatform.isDarwin [ ./darwin-fix-configure.patch ];
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
buildInputs = [libxml2 openssl bash]
|
|
++ lib.optional compressionSupport zlib;
|
|
|
|
strictDeps = true;
|
|
|
|
configureFlags = [
|
|
(lib.enableFeature shared "shared")
|
|
(lib.enableFeature static "static")
|
|
(lib.withFeature compressionSupport "zlib")
|
|
(lib.withFeature sslSupport "ssl")
|
|
];
|
|
|
|
preConfigure = ''
|
|
export PKG_CONFIG="$(command -v "$PKG_CONFIG")"
|
|
'';
|
|
|
|
passthru = {inherit compressionSupport sslSupport;};
|
|
|
|
meta = with lib; {
|
|
description = "HTTP and WebDAV client library";
|
|
mainProgram = "neon-config";
|
|
homepage = "https://notroj.github.io/neon/";
|
|
changelog = "https://github.com/notroj/${pname}/blob/${version}/NEWS";
|
|
platforms = platforms.unix;
|
|
license = licenses.lgpl2;
|
|
};
|
|
}
|