e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
74 lines
1.5 KiB
Nix
74 lines
1.5 KiB
Nix
{ dbus
|
|
, fetchFromGitLab
|
|
, gobject-introspection
|
|
, lib
|
|
, libadwaita
|
|
, meson
|
|
, ninja
|
|
, python3
|
|
, stdenv
|
|
, testers
|
|
, xvfb-run
|
|
}:
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "blueprint-compiler";
|
|
version = "0.12.0";
|
|
|
|
src = fetchFromGitLab {
|
|
domain = "gitlab.gnome.org";
|
|
owner = "jwestman";
|
|
repo = "blueprint-compiler";
|
|
rev = "v${finalAttrs.version}";
|
|
hash = "sha256-pvYSFCiYynH3E6QOTu4RfG+6eucq++yiRu75qucSlZU=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
];
|
|
|
|
buildInputs = [
|
|
libadwaita
|
|
(python3.withPackages (ps: with ps; [
|
|
pygobject3
|
|
]))
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
# For setup hook, so that the compiler can find typelib files
|
|
gobject-introspection
|
|
];
|
|
|
|
nativeCheckInputs = [
|
|
dbus
|
|
xvfb-run
|
|
];
|
|
|
|
# requires xvfb-run
|
|
doCheck = !stdenv.hostPlatform.isDarwin
|
|
&& false; # tests time out
|
|
|
|
checkPhase = ''
|
|
runHook preCheck
|
|
|
|
xvfb-run dbus-run-session \
|
|
--config-file=${dbus}/share/dbus-1/session.conf \
|
|
meson test --no-rebuild --print-errorlogs
|
|
|
|
runHook postCheck
|
|
'';
|
|
|
|
passthru.tests.version = testers.testVersion {
|
|
package = finalAttrs.finalPackage;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Markup language for GTK user interface files";
|
|
mainProgram = "blueprint-compiler";
|
|
homepage = "https://gitlab.gnome.org/jwestman/blueprint-compiler";
|
|
license = licenses.lgpl3Plus;
|
|
maintainers = with maintainers; [ benediktbroich ranfdev ];
|
|
platforms = platforms.unix;
|
|
};
|
|
})
|